home *** CD-ROM | disk | FTP | other *** search
/ The X-Philes (2nd Revision) / The X-Philes Number 1 (1995).iso / xphiles / hp48_2 / chip-48.src < prev    next >
Text File  |  1995-03-31  |  37KB  |  1,582 lines
  1. Article 1670 of comp.sys.handhelds:
  2. Path: en.ecn.purdue.edu!noose.ecn.purdue.edu!samsung!zaphod.mps.ohio-state.edu!sdd.hp.com!ucsd!ucbvax!bloom-beacon!eru!hagbard!sunic!news.funet.fi!funic!santra!news
  3. From: gson@niksula.hut.fi (Andreas Gustafsson)
  4. Newsgroups: comp.sys.handhelds
  5. Subject: Source code to CHIP-48 version 2.25
  6. Message-ID: <1990Oct6.183603.29151@santra.uucp>
  7. Date: 6 Oct 90 18:36:03 GMT
  8. Sender: news@santra.uucp (Cnews - USENET news system)
  9. Reply-To: gson@niksula.hut.fi (Andreas Gustafsson)
  10. Organization: Helsinki University of Technology, Finland
  11. Lines: 1567
  12.  
  13. Due to popular demand, I'm posting the complete source code for the
  14. CHIP-48 video game interpreter to comp.sys.handhelds.  I hope this
  15. will inspire others to write more free machine code software for the
  16. HP48SX.
  17.  
  18. The intention of this posting is not that people should actually
  19. assemble the code; it's much easier to get the binary which was
  20. posted recently and is also available by FTP from vega.hut.fi as
  21. /pub/misc/hp48sx/asap/chip48-2.25-bin.Z.  Rather, it should 
  22. serve as a source of programming tips for those writing their own
  23. machine code programs.
  24.  
  25. This source is written for the ASAP assembler, version 1.01.  ASAP is
  26. also FTP:able from vega.hut.fi.  To run the assembler, you need a
  27. 32-bit Unix machine and Perl 3.0 which is available from most major
  28. Unix archive sites.
  29.  
  30. Here it is.  Enjoy!
  31. ================================ Cut here ================================
  32. ; @(#) chip.asap 2.25 9/15/90
  33. ;
  34. ; chip.asap -- a CHIP-8 interpreter for the HP48SX
  35. ;
  36. ; (C) Copyright 1990 Andreas Gustafsson
  37. ;
  38. ;     Noncommercial distribution allowed, provided that this
  39. ;     copyright message is preserved, and any modified versions
  40. ;     are clearly marked as such.  
  41. ;
  42. ;     The program makes use of undocumented low-level features of
  43. ;     the HP48SX calculator, and may or may not cause loss of data,
  44. ;     excessive battery drainage, and/or damage to the calculator
  45. ;     hardware.  The Author takes no responsibility whatsoever for 
  46. ;     any damage caused by the use of this program.
  47. ;
  48. ;     THIS SOFTWARE IS PROVIDED "AS IS" AND WITHOUT ANY EXPRESS OR
  49. ;     IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED TO, THE IMPLIED
  50. ;     WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A PARTICULAR PURPOSE.
  51. ;
  52.  
  53. ;
  54. ; Register usage:
  55. ;
  56. ; d0 = general pointing
  57. ; d1 = points to chip-8 instruction (physical)
  58. ;
  59. ; r0 = CHIP-8 I register
  60. ; r1 = last time value
  61. ; r2 = physical address of virtual zero
  62. ; r3 = CHIP-8 PC
  63. ;
  64.  
  65. ; standard preamble for Kermit download
  66.     data.b    'H'
  67.     data.b    'P'
  68.     data.b    'H'
  69.     data.b    'P'
  70.     data.b    '4'
  71.     data.b    '8'
  72.     data.b    '-'
  73.     data.b    'A'
  74.     data.a    #2dcc        ; machine code object
  75. begin:    data.a    end-begin    ; length of object
  76. ; end of preamble
  77.  
  78.  
  79. ; HP48SX ROM locations
  80. ; These are for the Revision A ROM, they may need to be changed for
  81. ; other revisions.
  82.  
  83.     flush_kbd=#00d57    ; flush keyboard buffer
  84.     do_in_c=#01160        ; perform "in.4 c" instruction
  85.     alloc_str=#05b7d    ; allocate string
  86.     push_r0_shortint=#06537    ; push r0 as short integer, restore regs
  87.     save_rpl_regs=#0679b    ; save d0, d1, b, d
  88.     restore_rpl_regs=#067d2    ; restore d0, d1, b, d
  89.     check_1_arg=#18abf    ; make sure stack isn't empty
  90.  
  91. ; HP48SX RAM locations
  92.  
  93.     crcval=#00104        ; hardware CRC register
  94.     hwtimer=#00138        ; hardware timer
  95.     stackdisp_ptr=#7055B    ; contains address of stack display
  96.     menudisp_ptr=#70551    ; contains address of menu display
  97.     flags_37=#706ce        ; flags -37 to -40
  98.  
  99. ; data area layout (with a smarter assembler these offsets could be
  100. ; calculated automatically).
  101. ; Don't rearrange; in particular, the variables must be first and
  102. ; the order of the  "V10".."V15" pseudovariables is important.
  103.  
  104.     ofs_vars=0        ; CHIP-8 variables, 16 vars * 2 nibbles = 32
  105.     ofs_timer=32        ; delay timer "V10", size = 2
  106.     ofs_sound=34        ; sound timer "V11", size = 2
  107.     ofs_sndon=36        ; sound on/off flag "V12.0", size = 1
  108.     ofs_sdata=37        ; speaker data "V12.1", "V13", size = 3
  109.     ofs_ckeys=40        ; control key status "V14-15", size=4
  110.     ofs_csp=44        ; CHIP-8 stack pointer, size 5
  111.     ofs_cstack=49        ; CHIP-8 stack, size "stacknibbles" = 64
  112.     ofs_linetab=113        ; display row table, size 64 * 5 = 320
  113.     ofs_regsave=433        ; r0..r3 temporary save location, size = 20
  114.     ofs_end=453        ; end of data area
  115.  
  116. ; don't change these without updating the offsets above also
  117.     
  118.     stacklevels=16        ; size of CHIP-8 stack
  119.     stacknibbles=64        ; 4*stacklevels
  120.  
  121. ; execution begins here
  122.  
  123.     call.a    check_1_arg    ; check that stack is not empty
  124.  
  125.     call.a    save_rpl_regs    ; call ROM routine to save d0, d1, b, d
  126.  
  127.     ; if flag -40 (clock display) is set, clear it and exit.
  128.     ; This is because the clock display interrupt (or whatever)
  129.     ; causes problems, and doesn't get turned off just by clearing
  130.     ; the flag.  However, it does get turned off when the screen is 
  131.     ; redrawn after we exit, so the next time this program is started
  132.     ; it will run normally.
  133.     move.p5    flags_37,c
  134.     move.a    c,d0        ; point to flags -37..-40
  135.     move.p    @d0,a        ; get old flags
  136.     brbc    3,a,noclock    ; jump if flag -40 clear
  137.     clrb    3,a        ; clear flag -40
  138.     move.p    a,@d0        ; store updated flags
  139.     jump.3    exit        ; don't continue just yet
  140. noclock:
  141.  
  142.     ; allocate a string for temporary data storage
  143.  
  144.     clrb    #a,st        ; no garbage collection done
  145.     move.p5    ofs_end,c    ; size of uninitialized data area
  146.     call.a    alloc_str    ; call ROM routine to allocate a string
  147.     swap.a    c,d0
  148.     move.a    c,r4        ; now R4 points to the string
  149.  
  150.     ; clear the CHIP-8 variables and initialize some pseudovariables
  151.  
  152.     move.a    c,d0        ; point to variables (uses c value set above)
  153.     clr.w    c
  154.     move.w    c,@d0        ; clear V0..V7
  155.     add.a    16,d0
  156.     move.w    c,@d0        ; clear V8..VF
  157.     add.a    16,d0
  158.     move.p8    #40010000,c    ; set timers to #00, sndon to #1,
  159.                 ; and sdata to #400
  160.     move.8    c,@d0
  161.  
  162.     ; fill "linetab" with pointers to the display rows
  163.  
  164.     move.a    r4,a        ; get start of data area
  165.     move.p5    ofs_linetab,c
  166.     add.a    a,c
  167.     move.a    c,d0        ; d0 points to linetab
  168.  
  169.     move.p5    stackdisp_ptr,c    ; pointer to address of stack display
  170.     move.p2    56,a        ; 56 rows
  171.     call.3    ltfill
  172.     move.p5    menudisp_ptr,c    ; pointer to address of menu display
  173.     move.p2    8,a        ; 8 rows
  174.     call.3    ltfill
  175.  
  176.     ; allocate a 4 kB string for the CHIP-8 virtual memory
  177.  
  178.     clrb    #a,st        ; no garbage collection done
  179.     move.p5    #2000,c        ; 4 kB in nibbles
  180.     call.a    alloc_str    ; call ROM routine to allocate a string
  181.  
  182.     ; now r0 points to the header of the newly allocated string 
  183.     ; object, and d0 points to the data part
  184.  
  185.     swap.a    d0,c
  186.     move.a    c,r2        ; virtual zero in r2
  187.  
  188.     ; hate nondeterministic bugs...
  189.     clr.w    a
  190.     clr.w    b
  191.     clr.w    c
  192.     clr.w    d
  193.  
  194. chipmain:
  195.     ; copy the chip-8 program from the argument string to the virtual
  196.     ; chip-8 memory
  197.  
  198.     move.a    r2,a        ; get virtual zero
  199.     move.p5    #0400,c        ; virtual #0200 bytes
  200.     add.a    a,c
  201.     move.a    c,d0        ; now d0 points to virtual 0200
  202.  
  203.     move.a    @d1,c        ; point to the argument object
  204.     move.a    c,d1        ; (presumably a string)
  205.     move.a    @d1,a        ; get the object type
  206.     move.p5    #02a2c,c    ; string type prefix
  207.     brne.a    c,a,doerror    ; exit if it isn't a string
  208.     add.a    5,d1        ; skip the type
  209.     move.a    @d1,a        ; get the object length
  210.     sub.a    5,a        ; subtract length of length
  211.     move.p5    #01c00,c    ; this is #1000 - #0200 bytes in nibbles
  212.     brgt.a    c,a,nottoolong
  213. doerror:
  214.     jump.3    errexit        ; string will not fit in 4 k
  215. nottoolong:
  216.     add.a    5,d1        ; point to the object itself
  217.     call.3    copynibbles
  218.  
  219.     ; pop the argument string off the stack
  220.     call.a    restore_rpl_regs
  221.     add.a    5,d1
  222.     inc.a    d
  223.     call.a    save_rpl_regs
  224.  
  225.     ; copy the hexadecimal character font to the virtual chip-8 memory,
  226.     ; unpacking it on-the-fly
  227.  
  228.     move.a    r2,c            ; get virtual zero
  229.     move.a    c,d0            ; now d0 points to 0000 virtual
  230.     move.a    pc,a
  231. ref17:    move.p5    hexfont-ref17,c
  232.     add.a    a,c
  233.     move.a    c,d1            ; now d1 points to the hex patterns
  234.     move.p2    hexfontend-hexfont,a    ; length (8 bits are enough)
  235. fontcopylo:
  236.     move.1    @d1,c            ; read a nibble
  237.     sln.a    c            ; shift to high nibble in byte
  238.     add.a    1,d1
  239.     move.2    c,@d0            ; store byte
  240.     add.a    2,d0            
  241.     dec.a    a
  242.     brnz.b    a,fontcopylo
  243.  
  244.     intoff
  245.  
  246. ; jump here when the "restart" key is pressed
  247. restart:
  248.  
  249.     ; initialize PC and I
  250.     clr.a    c
  251.     move.a    c,r0        ; I=0000 in r0
  252.     move.p3    #200,c        ; relies on c being cleared
  253.     move.a    c,r3        ; PC=0200 in r3
  254.  
  255.     ; initialize stack pointer
  256.  
  257.     move.a    r4,a        ; get start of data area
  258.     move.p5    ofs_csp,c
  259.     add.a    a,c
  260.     move.a    c,d0        ; d0 now points to csp
  261.  
  262.     clr.a    c
  263.     move.a    c,@d0        ; csp cleared
  264.  
  265.     call.3    i00e0        ; erase display
  266.  
  267.     ; initialize the time value
  268.  
  269.     clr.a    c        ; must clear all of c for comparison below
  270.     move.p3    hwtimer,c
  271.     move.a    c,d0        ; point to hardware timer
  272.     move.a    @d0,c
  273. retry1:    move.a    c,a
  274.     move.a    @d0,c
  275.     brne.a    c,a,retry1    ; loop until we get same value twice
  276.  
  277.     move.p5    #00F80,a    ; mask away 7 low bits of time value
  278.     and.a    a,c
  279.     move.a    a,r1
  280.  
  281. nextinstr:
  282.     call.3    realtime    ; do real-time chores
  283.     brcc    nocarry
  284. rtcarry:
  285.     brbs    4,a,restart    ; ENTER was pressed
  286.     ; otherwise, the abort key was pressed; make a clean exit
  287.  
  288. exit:
  289.     call.a    restore_rpl_regs
  290.  
  291.     move.a    @d0,a        ; dispatch next RPL instruction
  292.     add.a    5,d0
  293.     jump.a    @a
  294.  
  295. nocarry:
  296.     ; There appears to be some kind of interrupt that 
  297.     ; checks the keyboard status, and that doesn't get
  298.     ; turned off by "intoff".  Not knowing how to turn it off, we
  299.     ; try to live with it by flushing the keyboard buffer ever so
  300.     ; often, and trying to keep the "out" register zeroed most of
  301.     ; the time (so that the keyboard will appear inactive when
  302.     ; the interrupt checks it, even if keys really are being pressed).
  303.  
  304.     intoff            ; just in case someone turned them on again
  305.  
  306.     call.a    flush_kbd    ; flush keyboard buffer (trashes d1 and c)
  307.  
  308. dispatch:
  309.     ; dispatch a CHIP-8 instruction
  310.     move.a    r3,c    ; get cpc
  311.     move.a    c,a    ; keep unincremented value
  312.     add.a    2,a    ; increment cpc by 2 bytes
  313.     move.a    a,r3    ; store incremented cpc
  314.     call.3    virtophy ; unincremented value is in c
  315.     move.a    c,d1    ; store virtual pc in d1
  316.  
  317.     clr.a     c
  318.     add.a    1,d1    ; point to MSN
  319.     move.p    @d1,c    ; get MSN of first byte of CHIP-8 instruction
  320.     sub.a    1,d1    ; back to beginning of instruction
  321.     add.a    c,c
  322.     add.a    c,c    ; now c = nibble * 4
  323.  
  324.     move.a    pc,a
  325. ref6:    add.a    c,a
  326.     move.p5    jumptab-ref6,c
  327.     add.a    a,c    ; now c = jumptab + nibble * 4
  328.     move.a    c,d0
  329.     clr.a    c    ; clear the 5th nibble
  330.     move.4    @d0,c    ; now c = jumptab entry
  331.  
  332.     move.a    pc,a
  333. jtref:    add.a    c,a    ; now a = jump address
  334.  
  335.     move.a     pc,c
  336. retref:    add.a    retloc-retref,c
  337.     push.a    c    ; push return address on stack
  338.     jump.a    a    ; jump to instruction routine
  339.  
  340. retloc:
  341.     brcs    errexit    ; if carry is set, an error has occurred
  342.     jump.3    nextinstr
  343.  
  344. errexit:    
  345.     move.w    r3,c        ; get the current CHIP-8 PC value
  346.     move.w    c,r0        ; move to R0
  347.     call.a    push_r0_shortint ; ROM routine: push short integer from R0
  348.                 ; (this also restores saved d0, d1, b, d)
  349.     call.a    save_rpl_regs    ; save the registers again (redundant?)
  350.     jump.3    exit
  351.  
  352.  
  353. ; ltfill -- fill a part of "linetab"
  354. ltfill:
  355.     move.a    c,d1
  356.     move.a    @d1,c    ; get display address
  357.     add.a    16,c    ; increment past the GROB header (20 nibbles)
  358.     add.a    4,c
  359. ltfill_loop:
  360.     move.a    c,@d0
  361.     add.a    16,c    ; increment to next row (34 nibbles)
  362.     add.a    16,c    
  363.     add.a    2,c
  364.     add.a    5,d0
  365.     dec.b    a
  366.     brnz.b    a,ltfill_loop
  367.     ret
  368.  
  369.  
  370. ; copynibbles -- copy a memory block
  371. ;
  372. ; d1 points to source, d0 to destination, and 
  373. ; a contains the number of nibbles to copy
  374. copynibbles:
  375. copylo:
  376.     brz.a    a,copyend
  377.     move.1    @d1,c
  378.     move.1    c,@d0
  379.     add.a    1,d0
  380.     add.a    1,d1
  381.     dec.a    a
  382.     jump.3    copylo
  383. copyend:
  384.     ret
  385.  
  386. ; realtime -- do various timer-driven real-time processing
  387. ;
  388. ; In: nothing
  389. ; Out: carry set iff real-time keypress detected; key code is in a
  390. ; Uses: all 16 nibbles of a and c; d0
  391. ;       but neither b nor d
  392. ;
  393. realtime:
  394.  
  395.     ; flip the speaker if the sound is on
  396.     call.3    soundpd0    ; point to sound timer
  397.     move.b    @d0,c
  398.     brz.b    c,silent
  399.     add.a    2,d0        ; point to sound on/off flag
  400.     move.p    @d0,c
  401.     brz.p    c,silent
  402.     add.a    1,d0        ; point to speaker data
  403.     move.3    @d0,c
  404.     out.x    c
  405.     not.x    c    ; turn #400 into #800 and vice versa
  406.     move.p3    #c00,a
  407.     and.x    a,c
  408.     move.3    c,@d0
  409. silent:
  410.  
  411.     ; check the hardware timer register to see if it is time for
  412.     ; a 64 Hz realtime clock tick
  413.  
  414.     clr.a    c        ; must clear all of c for comparison below
  415.     move.p3    hwtimer,c
  416.     move.a    c,d0
  417.     move.a    @d0,c
  418. retry2:    move.a    c,a
  419.     move.a    @d0,c
  420.     brne.a    c,a,retry2    ; loop until we get same value twice
  421.  
  422.     move.p5    #00F80,a    ; mask away 7 low bits of time value
  423.     and.a    a,c
  424.  
  425.     move.a    r1,a        ; now a is old value, c is new value
  426.     brne.a    c,a,dotick
  427.     jump.3    notick        ; code at notick depends on c.0 being zero
  428.  
  429. dotick:    ; handle a 64 Hz tick
  430.  
  431.     clr.a    c        ; decrement r1 by #80
  432.     move.p2    #80,c
  433.     sub.a    c,a
  434.     move.p5    #00F80,c    ; mask 
  435.     and.a    c,a
  436.     move.a    a,r1
  437.  
  438.     call.3    timerpd0    ; point to delay timer
  439.     move.b    @d0,c
  440.     brz.b    c,timerzero
  441.     dec.b    c
  442.     move.b    c,@d0
  443. timerzero:
  444.  
  445.     add.a    2,d0        ; point to sound timer
  446.     move.b    @d0,c
  447.     brz.b    c,soundzero
  448.     dec.b    c
  449.     move.b    c,@d0
  450. soundzero:
  451.  
  452.     ; check for various control keys
  453.  
  454.     call.3    ckeyspd0    ; point d0 to key status
  455.  
  456.     move.p3    #010,c        ; row ENTER..backstep
  457.     out.x    c
  458.     call.a    do_in_c
  459.     move.a    c,a        ; save "in" data in a
  460.     clr.a    c
  461.     out.x    c        ; zero "out" port as fast as possible
  462.  
  463.     move.4    @d0,c        ; get previous key status
  464.     move.4    a,@d0        ; save current key status
  465.     not.a    a        ; get keys that are not pressed
  466.     and.a    c,a        ; ..but were..
  467.     retbs    4,a        ; return with carry set if ENTER pressed
  468.     retbs    0,a        ; same for the backstep key
  469.     brbs    3,a,togglesound    ; +/-
  470. noabort:
  471.     move.p1    #1,c    ; set flag to indicate that a tick took place
  472. notick:    
  473.     retclrc        ; return tick flag in c.0
  474.  
  475.  
  476. ; toggle the sound flag (this is jumped to when the +/- key is pressed)
  477. togglesound:
  478.     call.3    sndonpd0
  479.     move.p    @d0,c
  480.     not.a    c
  481.     move.p1    #1,a
  482.     and.a    a,c
  483.     move.p    c,@d0
  484.     jump.3    noabort
  485.     
  486.  
  487. ; nnnc - get NNN field of current instruction to c register
  488. ;
  489. ; In:    d1 pointing to chip-8 instruction
  490. ; Out:    NNN field of instruction in c (5 valid nibbles)
  491. ; Uses: none
  492. nnnc:
  493.     clr.a     c    ; clear nibbles 3..4
  494.     move.1    2,p
  495.     move.p    @d1,c    ; set nibble 2
  496.     move.1    0,p
  497.     add.a    2,d1    ; point to second byte of instruction
  498.     move.b    @d1,c    ; set nibbles 0 and 1
  499.     sub.a    2,d1    ; restore d1
  500.     ret
  501.  
  502.  
  503. ; virtophy -- convert virtual address to physical address
  504. ;
  505. ; In:   virtual address in c
  506. ; Out:  physical address in c
  507. ; Uses: a
  508. virtophy:
  509.     add.a    c,c    ; convert bytes to nibbles
  510.     move.a    r2,a    ; convert virtual to physical
  511.     add.a    a,c
  512.     ret
  513.  
  514.  
  515. ; varpd0 - get pointer to variable to d0
  516. ; 
  517. ; In:    d1 points to nibble containing variable number
  518. ; Out:    d0 points to variable
  519. ; Uses: a,c
  520. varpd0:
  521.     clr.a     c
  522.     move.p    @d1,c    ; get nibble with variable number
  523. cvarpd0:
  524.     add.a    c,c    ; convert bytes to nibbles
  525.     move.a    r4,a
  526.     add.a    a,c
  527.     move.a    c,d0
  528.     ret
  529.  
  530.  
  531. ; var0pd0 -- load d0 with pointer to V0
  532. ;
  533. ; In:    none
  534. ; Out:    d0 points to variable 0
  535. ; Uses: a,c
  536. var0pd0:
  537.     clr.a     c
  538.     move.p1    #0,c
  539.     jump.3    cvarpd0
  540.  
  541.  
  542. ; varfpd0 -- load d0 with pointer to VF
  543. ;
  544. ; In:    none
  545. ; Out:    d0 points to variable F
  546. ; Uses: a,c
  547. varfpd0:
  548.     clr.a     c
  549.     move.p1    #f,c
  550.     jump.3    cvarpd0
  551.  
  552. timerpd0:
  553.     clr.a    c
  554.     move.p2    #10,c
  555.     jump.3    cvarpd0    ; point d0 to timer
  556.  
  557. soundpd0:
  558.     clr.a    c
  559.     move.p2    #11,c
  560.     jump.3    cvarpd0    ; point d0 to sound timer
  561.  
  562. sndonpd0:
  563.     clr.a    c
  564.     move.p2    #12,c
  565.     jump.3    cvarpd0    ; point d0 to sound on/off flag
  566.  
  567. ckeyspd0:
  568.     clr.a    c
  569.     move.p2    #14,c
  570.     jump.3    cvarpd0    ; point d0 to control key status
  571.  
  572.  
  573. ; varxcvarya -- get values of X and Y variables
  574. ; In:    d1 points to instruction
  575. ; Out:    c contains VX, zero padded to .a field
  576. ;    a contains VY, zero padded to .a field
  577. ; Uses:    d0
  578. varxcvarya:
  579.     call.3    varpd0    ; get pointer to X
  580.     clr.a    c
  581.     move.b    @d0,c    ; get X value
  582.     push.a    c
  583.     add.a    3,d1    ; point to Y nibble in instruction
  584.     call.3    varpd0    ; get pointer to Y
  585.     clr.a    a
  586.     move.b    @d0,a    ; get Y value
  587.     pop.a    c
  588.     sub.a    3,d1    ; back to beginning of instruction
  589.     ret
  590.  
  591.  
  592. ; In:    d1 points to beginning instruction
  593. ; Out:    c contains VX (5 nibbles valid)
  594. ;    a contains VY (5 nibbles valid)
  595. ;    d0 points to VX
  596. ; Uses: none
  597. alusetup:
  598.     add.a    3,d1    ; point to Y nibble in instruction
  599.     call.3    varpd0
  600.     sub.a    3,d1
  601.     clr.a    c
  602.     move.2    @d0,c    ; VY in c
  603.     push.a    c
  604.     call.3    varpd0    ; d0 is pointer to VX
  605.     clr.a    a
  606.     move.2    @d0,a    ; VX in a
  607.     pop.a    c    ; VY in c
  608.     swap.a    a,c    ; now VX in c and VY in a
  609.     ret
  610.  
  611. savecarry:
  612.     srn.a    c    ; extract the carry byte
  613.     srn.a    c
  614. lsbcarry:
  615.     move.p2    #01,a    ; use low bit only
  616.     and.b    a,c        
  617.     push.a    c
  618.     call.3    varfpd0    ; get a pointer to VF
  619.     pop.a    c
  620.     move.b    c,@d0    ; store the carry byte
  621.     retclrc
  622.  
  623.  
  624. ; testkey -- check whether a given hex key is pressed
  625. ;
  626. ; In: key number in c (5 low nibbles must be valid)
  627. ; Out: low nibble of c is nonzero iff key is pressed
  628. ; Uses: a,d0
  629. testkey:
  630.     add.a    c,c    ; index into keytab
  631.     move.a    pc,a
  632. ref16:    add.a    c,a
  633.     move.p5    keytab-ref16,c
  634.     add.a    a,c
  635.     move.a    c,d0    ; now d0 points to keytab
  636.     clr.a    c
  637.     move.1    @d0,c    ; get "out" data
  638.     out.x    c
  639.     call.a    do_in_c
  640.     move.a    c,a    ; store the input value in a
  641.     clr.a    c
  642.     out.x    c    ; zero "out" port as fast as possible
  643.     add.a    1,d0
  644.     move.1    @d0,c    ; get "in" mask
  645.     and.a    a,c
  646.     ret
  647.  
  648. ; setup subroutine for fx55 or fx65 instruction
  649. ;
  650. ; In: d0 points to VX
  651. ; Out: d0 points to to V0, a points to VX, and d1 points to MI
  652. varcopysetup:
  653.     swap.a    c,d0        ; copy d0 to c
  654.     move.a    c,d0
  655.     push.a    c        ; save pointer to the last variable
  656.     call.3    var0pd0        ; point d0 to first variable (v0)
  657.     move.a    r0,c        ; get I
  658.     call.3    virtophy
  659.     move.a    c,d1        ; point d1 to data at I
  660.     pop.a    c
  661.     move.a    c,a        ; now a contains pointer to last var.
  662.     ret
  663.  
  664.  
  665. i0:    ; mcode call 
  666.     call.3    nnnc
  667.     move.a    c,a    ; routine address is now in a
  668.     clr.a    c
  669.     move.p2    #e0,c
  670.     breq.a    c,a,i00e0
  671.     move.p2    #ee,c
  672.     breq.a    c,a,i00ee
  673.     retsetc        ; illegal mcode call
  674.  
  675. i00e0:    ; erase screen
  676.     move.a    r4,a        ; get start of data area
  677.     move.p5    ofs_linetab,c
  678.     add.a    c,a
  679.  
  680.     ; a contains linetab pointer
  681.     ; b counts down from 64
  682.     move.p2    64,c
  683.     move.a    c,b
  684. eraselo:
  685.     move.a    a,d0
  686.     move.a    @d0,c
  687.     move.a    c,d0    ; d0 now points to display memory
  688.     clr.w    c
  689.     move.w    c,@d0    ; erase 16 nibbles
  690.     add.a    16,d0
  691.     move.w    c,@d0    ; and 16 more
  692.     add.a    16,d0
  693.     move.b    c,@d0    ; and 2 more, total 34
  694.     add.a    5,a
  695.     dec.b    b
  696.     brnz.b    b,eraselo
  697.     retclrc
  698.  
  699.         
  700. i00ee:    ; subroutine return
  701.     move.a    r4,a        ; get start of data area
  702.     move.p5    ofs_csp,c
  703.     add.a    a,c
  704.     move.a    c,d0    ; c and d0 both point to csp
  705.     move.a    @d0,a    ; now a contains the chip-8 stack pointer (0..4n-4)
  706.     retz.a    a    ; return with carry set if stack underflow
  707.     sub.a    4,a    ; drop one level
  708.     move.a    a,@d0    ; save new csp
  709.     add.a    5,c    ; point c at stack[0]
  710.     add.a    a,c    ; point c at popped level
  711.     move.a    c,d0    ; point d0 at popped level
  712.     clr.a    c
  713.     move.4    @d0,c
  714.     move.a    c,r3    ; set pc
  715.     retclrc
  716.  
  717. i1:    ; 1NNN, jump
  718. dojmp:    call.3    nnnc
  719.     move.a    c,r3    ; assign to pc
  720.     retclrc
  721.  
  722. i2:    ; 2NNN, subroutine call
  723.     move.a    r4,a    ; get start of data area
  724.     move.p5    ofs_csp,c
  725.     add.a    a,c
  726.  
  727.     move.a    c,d0    ; d0 and c both point to csp
  728.     move.a    @d0,a    ; now a contains the chip-8 stack pointer (0..4n-4)
  729.             ; c still points at csp
  730.     add.a    5,c    ; point c at stack[0]
  731.     add.a    a,c    ; point c at first free stack level
  732.     swap.a    c,d0    ; now d0 points to free stack and c points to csp
  733.     move.a    r3,a    ; get pc
  734.     move.4    a,@d0    ; store pc in stack
  735.     swap.a    c,d0    ; now d0 points to cpc again
  736.     move.a    @d0,a    ; now a contains the chip-8 stack pointer (0..4n-4)
  737.     add.a    4,a
  738.     move.p5    stacknibbles,c
  739.     retlt.a    c,a    ; return with carry set if stack overflow
  740.     move.a    a,@d0    ; store incremented sp
  741.     jump.3    dojmp    ; the reset is like 1nnn
  742.  
  743.  
  744. i3:    ; 3XKK, skip if X==KK
  745.     call.3    varpd0    ; get pointer to X
  746.     add.a    2,d1    ; point to second byte of instruction
  747.     move.b    @d1,a    ; now a = KK
  748.     move.b    @d0,c    ; now c = VX
  749. skipeq:
  750.     brne.b    c,a,noskip
  751. doskip:    swap.a    c,r3    ; increment cpc by 2
  752.     add.a    2,c
  753.     swap.a    c,r3
  754. noskip:
  755.     retclrc
  756.  
  757. i4:    ; 4XKK, skip if X<>KK
  758.     call.3    varpd0    ; get pointer to X
  759.     add.a    2,d1    ; point to second byte of instruction
  760.     move.b    @d1,a    ; now a = KK
  761.     move.b    @d0,c    ; now c = VX
  762. skipne:
  763.     breq.b    c,a,noskip
  764.     jump.3    doskip
  765.  
  766. i5:    ; 5XY0, skip if X==Y
  767.     call.3    varxcvarya    ; get VX to c, VY to a
  768.     jump.3    skipeq
  769.  
  770. i9:    ; 9XY0, skip if X!=Y
  771.     call.3    varxcvarya    ; get VX to c, VY to a
  772.     jump.3    skipne
  773.  
  774. i6:    ; 6XKK, load variable by constant
  775.     call.3    varpd0    ; get pointer to X
  776.     add.a    2,d1    ; point to second byte of instruction
  777.     move.b    @d1,a    ; now a = KK
  778.     move.b    a,@d0    ; store in variable
  779.     retclrc
  780.  
  781. i7:    ; 7XKK, add constant to variable
  782.     call.3    varpd0    ; get pointer to X
  783.     add.a    2,d1    ; point to second byte of instruction
  784.     move.b    @d1,a    ; now a = KK
  785.     move.b    @d0,c    ; get old value
  786.     add.b    a,c    ; add KK
  787.     move.b    c,@d0    ; store new value
  788.     retclrc
  789.  
  790.  
  791. i8:    ; arithmetic and logic operations
  792.     add.a    2,d1    ; point to last nibble of instruction
  793.     move.1    @d1,a
  794.     sub.a    2,d1
  795.  
  796.     move.p1    #0,c
  797.     brne.p    c,a,noti8xy0
  798. i8xy0:    ; VX := VY
  799.     call.3    alusetup
  800.     move.b    a,@d0    ; store result
  801.     retclrc
  802. noti8xy0:
  803.  
  804.     move.p1    #1,c
  805.     brne.p    c,a,noti8xy1
  806. i8xy1:    ; VX := VX or VY
  807.     call.3    alusetup
  808.     or.b    a,c
  809.     move.2    c,@d0    ; store result
  810.     retclrc
  811. noti8xy1:
  812.  
  813.     move.p1    #2,c
  814.     brne.p    c,a,noti8xy2
  815. i8xy2:    ; VX := VX and VY
  816.     call.3    alusetup
  817.     and.b    a,c
  818.     move.2    c,@d0    ; store result
  819.     retclrc
  820. noti8xy2:
  821.  
  822.     move.p1    #3,c
  823.     brne.p    c,a,noti8xy3
  824. i8xy3:    ; VX := VX xor VY
  825.     call.3    alusetup
  826.     move.b    a,b
  827.     or.b    c,b    ; (x or y) in b
  828.     and.b    a,c    ; (x and y) in c
  829.     not.b    c    
  830.     and.b    b,c    ; (x xor y) in c
  831.     move.b    c,@d0    ; store result
  832.     retclrc
  833. noti8xy3:
  834.  
  835.     move.p1    #4,c
  836.     brne.p    c,a,noti8xy4
  837. i8xy4:    ; VX := VX + VY; carry in VF
  838.     call.3    alusetup
  839.     add.a    a,c
  840.     move.2    c,@d0
  841.     jump.3    savecarry
  842. noti8xy4:
  843.  
  844.     move.p1    #5,c
  845.     brne.p    c,a,noti8xy5
  846. i8xy5:    ; VX := VX - VY; carry in VF
  847.     call.3    alusetup
  848. subcommon:
  849.     not.b    a    ; do monkey business to get inverted carry
  850.     add.a    a,c
  851.     inc.a    c
  852.     move.2    c,@d0
  853.     jump.3    savecarry
  854. noti8xy5:
  855.  
  856.     move.p1    #6,c
  857.     brne.p    c,a,noti8xy6
  858. i8xy6:    ; VX := VX >> 1; carry in VF
  859.     call.3    alusetup
  860.     move.b    c,a    
  861.     srb.b    c
  862.     move.2    c,@d0    ; store result
  863.     move.b    a,c    ; use low bit of original byte for carry
  864.     jump.3    lsbcarry
  865. noti8xy6:
  866.     move.p1    #7,c
  867.     brne.p    c,a,noti8xy7
  868. i8xy7:    ; VX := VY - VX; carry in VF
  869.     call.3    alusetup
  870.     swap.a    a,c
  871.     jump.3    subcommon
  872.  
  873. noti8xy7:
  874.     move.p1    #e,c
  875.     brne.p    c,a,noti8xye
  876. i8xye:    ; VX := VX << 1; carry in VF
  877.     call.3    alusetup
  878.     add.a    c,c
  879.     move.2    c,@d0
  880.     jump.3    savecarry
  881. noti8xye:
  882.     retsetc
  883.  
  884.  
  885. ia:    ; ANNN, set I
  886.     call.3    nnnc
  887.     move.a    c,r0    ; assign to I
  888.     retclrc
  889.  
  890. ib:    ; parametric jump to NNN+V0
  891.     call.3    varpd0
  892.     call.3    nnnc
  893.     clr.a    a
  894.     move.b    @d0,a
  895.     add.a    a,c
  896.     move.a    c,r3    ; assign to pc
  897.     retclrc
  898.  
  899.  
  900. ic:    ; pseudo-random number
  901.  
  902.     call.3    varpd0        ; now d0 points to VX
  903.     move.p5    crcval,c
  904.     swap.a    c,d0        ; point d0 to hardware crc
  905.     move.2    @d0,a        ; read the low byte of the crc
  906.     swap.a    c,d0        ; now d0 points to VX again
  907.     add.a    2,d1        ; point to second byte of instruction
  908.     move.b    @d1,c        ; get mask
  909.     sub.a    2,d1        ; restore d1
  910.     and.b    a,c        ; mask
  911.     move.b    c,@d0        ; store result
  912.     retclrc
  913.  
  914.  
  915. id_abort:
  916.     jump.3    fx0a_abort
  917.  
  918.  
  919. id:    ; DXYN, show N-byte sprite at MI at screen coordinates (X,Y)
  920.     ;       I doesn't change
  921.  
  922.     ; synchronize with 64 Hz tick
  923. tickwait:
  924.     call.3    realtime
  925.     brcs    id_abort    ; a realtime key was pressed
  926.     brz.p    c,tickwait    ; wait until a tick occus
  927.  
  928.     call.3    save_rregs    ; save r0..r3
  929.  
  930.     move.a    r0,c        ; get I
  931.     call.3    virtophy
  932.     move.a    c,r0        ; now r0 points to sprite
  933.  
  934.     call.3    varxcvarya
  935.     move.a    c,d        ; save X in d
  936.     move.p2    #1f,c
  937.     and.b    c,a        ; mask Y to range 0..31, leave in a
  938.     move.p2    #3f,c
  939.     and.b    c,d        ; mask X to range 0..63, save in d
  940.  
  941.     ; get the number of bytes in the sprite (preserving a and d)
  942.     add.a    2,d1        ; point to N field
  943.  
  944.     clr.b    c
  945.     move.1    @d1,c
  946.     add.b    a,c        ; now c contains Y + sprite length
  947.     move.b    c,b
  948.     move.p2    #20,c
  949.     sub.b    c,b        ; now b contains no. of overshoot lines
  950.     brcc    oshoot
  951.     clr.b    b        ; no overshoot
  952. oshoot:
  953.     clr.b    c        ; get sprite length again
  954.     move.1    @d1,c
  955.     sub.b    b,c        ; subtract overshoot
  956.     move.1    c,0,p        ; now p contains adjusted length
  957.     move.1    p,c,15        ; byte counter in nibble 15 of c
  958.     move.1    14,p
  959.     clr.p    c        ; collision flag in nibble 14 of c
  960.     move.1    0,p
  961.     sub.a    2,d1        ; back to beginning of instruction
  962.  
  963.     call.3    sprite        ; do it
  964.  
  965.     call.3    restore_rregs
  966.  
  967.     call.4    varfpd0        ; d0 points to VF
  968.     clr.b    c
  969.     move.1    14,p
  970.     brz.p    c,nocolls
  971.     inc.b    c
  972. nocolls:
  973.     move.b    c,@d0        ; store collision flag
  974.     move.1    0,p
  975.  
  976.     retclrc    ; id
  977.  
  978.  
  979. ie:    ; skip on key pressed / not pressed
  980.     call.3    varpd0
  981.     clr.a    c
  982.     move.b    @d0,c    ; Telmac key number
  983.     call.3    testkey
  984.     clr.b    d
  985.     move.p    c,d    ; now d.b is nonzero iff key was pressed
  986.     
  987.     add.a    2,d1    ; point to second byte of instruction
  988.     move.b    @d1,a
  989.     sub.a    2,d1
  990.     move.p2    #9e,c
  991.     breq.b    c,a,doex9e
  992.     move.p2    #a1,c
  993.     breq.b    c,a,doexa1
  994.     retsetc
  995.  
  996. doex9e:    move.b    d,c
  997.     clr.b    a
  998.     jump.3    skipne    ; skip iff d!=0 (key was pressed)
  999.  
  1000. doexa1:    move.b    d,c
  1001.     clr.b    a
  1002.     jump.3    skipeq    ; skip iff d==0 (key was not pressed)
  1003.  
  1004.  
  1005. ; kwait -- wait for key, return it in low byte of c
  1006. ; In: none
  1007. ; Out: key code in low byte of c
  1008. ; Uses: most everything except d0
  1009. ;
  1010. ; The beep-and-wait-until-released behaviour may seem a bit crummy,
  1011. ; but we're just trying to emulate the original Telmac PROM monitor
  1012. ; keyboard input routine as closely as possible.
  1013. kwait:
  1014.     swap.a    c,d0
  1015.     push.a    c        ; save d0 value
  1016.  
  1017.     clr.a    d        ; low nibble of d used for key code
  1018. kwalo:    move.a    d,c
  1019.     call.3    testkey
  1020.     brnz.p    c,pressed
  1021.     call.3    realtime    ; preserves d
  1022.     brcs    kwabort
  1023.     inc.p    d        ; loop through keys 0..15
  1024.     jump.3    kwalo
  1025.  
  1026. pressed:
  1027.     call.3    soundpd0
  1028.     move.p2    #04,c
  1029.     move.2    c,@d0        ; set sound timer to #04
  1030.     call.3    realtime    ; make some noise
  1031.     brcs    kwabort
  1032.     move.a    d,c
  1033.     call.3    testkey
  1034.     brnz.p    c,pressed    ; wait until key is released
  1035.  
  1036.     pop.a    c        ; restore d0 value
  1037.     move.a    c,d0
  1038.     move.b    d,c
  1039.     retclrc
  1040.  
  1041. kwabort:
  1042.     pop.a    c        ; adjust stack
  1043.     retsetc
  1044.  
  1045. if:    ; misc. functions using VX
  1046.     ; d0 is set up to point to VX
  1047.  
  1048.     call.3    varpd0
  1049.     add.a    2,d1    ; point to second byte of instruction
  1050.     move.b    @d1,a
  1051.     sub.a    2,d1
  1052.  
  1053.     move.p2    #07,c
  1054.     brne.b    c,a,notifx07
  1055. ifx07:    ; read timer
  1056.     swap.a    c,d0
  1057.     push.a    c
  1058.     call.3    timerpd0
  1059.     move.b    @d0,a
  1060.     pop.a    c
  1061.     swap.a    c,d0
  1062.     move.b    a,@d0
  1063.     retclrc
  1064. notifx07:
  1065.  
  1066.     move.p2    #0a,c
  1067.     brne.b    c,a,notifx0a
  1068. ifx0a:    call.3    kwait
  1069.     brcs    fx0a_abort
  1070.     move.b    c,@d0
  1071.     retclrc
  1072. fx0a_abort:
  1073.     pop.a    c    ; adjust stack for forced return
  1074.     jump.3    rtcarry
  1075.  
  1076. notifx0a:
  1077.  
  1078.      move.p2    #15,c
  1079.     brne.b    c,a,notifx15
  1080. ifx15:    ; set timer
  1081.     move.b    @d0,c
  1082.     push.a    c
  1083.     call.3    timerpd0
  1084.     pop.a    c
  1085.     move.b    c,@d0
  1086.     retclrc
  1087. notifx15:
  1088.  
  1089.      move.p2    #18,c
  1090.     brne.b    c,a,notifx18
  1091. ifx18:    ; set sound
  1092.     move.b    @d0,c
  1093.     push.a    c
  1094.     call.3    soundpd0
  1095.     pop.a    c
  1096.     move.b    c,@d0
  1097.     retclrc
  1098. notifx18:
  1099.  
  1100.      move.p2    #1e,c
  1101.     brne.b    c,a,notifx1e
  1102. ifx1e:    ; increment I by VX
  1103.     clr.a    c
  1104.     move.b    @d0,c
  1105.     move.a    r0,a    ; get old I
  1106.     add.x    c,a    ; increment, modifying only 3 low nibbles
  1107.     retcs        ; it wrapped around #1000
  1108.     move.a    a,r0    ; save new I
  1109.     retclrc
  1110. notifx1e:
  1111.  
  1112.      move.p2    #29,c
  1113.     brne.b    c,a,notifx29
  1114. ifx29:    ; point to hex display pattern
  1115.     ; assumes that the hex patterns are at virtual 0000
  1116.     clr.a    c
  1117.     move.1    @d0,c    ; use low nibble of variable
  1118.     move.a    c,a    
  1119.     add.a    c,c    ; * 2
  1120.     add.a    c,c    ; * 4
  1121.     add.a    a,c    ; * 5
  1122.     move.a    c,r0    ; this is the new I
  1123.     retclrc
  1124. notifx29:
  1125.  
  1126.      move.p2    #33,c
  1127.     breq.b    c,a,ifx33
  1128.     jump.3    notifx33
  1129. ifx33:    ; 8-bit binary to decimal conversion
  1130.     move.b    @d0,c
  1131.     move.b    c,d        ; d contains the byte to convert
  1132.  
  1133.     move.a    pc,a
  1134. ref12:    move.p5    dectab-ref12,c
  1135.     add.a    a,c
  1136.     move.a    c,d0        ; d0 points to the conversion table
  1137.  
  1138.     clr.a    a        ; a accumulates decimal result    
  1139. cnvbit:    brz.b    d,cnvend
  1140.     move.b    d,c
  1141.     brbc    0,c,skpbit    ; jump if low-order bit is zero
  1142.     move.3    @d0,c
  1143.     setdec
  1144.     add.a    c,a        ; only 3 low nibbles contain real data
  1145.     sethex
  1146. skpbit:    add.a    3,d0
  1147.     srb.b    d
  1148.     jump.3    cnvbit
  1149.  
  1150. cnvabort:
  1151.     retsetc
  1152.  
  1153. cnvend:
  1154.     move.a    a,b        ; save the decimal value
  1155.     move.a    r0,c        ; get I
  1156.     move.p5    #00ffd,a    ; is I > 0FFD hex?
  1157.     retgt.a    c,a        ; protect memory above 0FFF
  1158.     call.3    virtophy
  1159.     move.a    c,d0        ; virtual I in d0
  1160.     move.a    b,a        ; restore the decimal value
  1161.  
  1162.     clr.a    c
  1163.     move.1    2,p
  1164.     move.p    a,@d0        ; most significant digit first
  1165.     add.a    1,d0
  1166.     move.p    c,@d0        ; zero
  1167.     add.a    1,d0
  1168.     move.1    1,p
  1169.     move.p    a,@d0        ; middle digit
  1170.     add.a    1,d0
  1171.     move.p    c,@d0        ; zero
  1172.     add.a    1,d0
  1173.     move.1    0,p
  1174.     move.p    a,@d0        ; least significant digit
  1175.     add.a    1,d0
  1176.     move.p    c,@d0        ; zero
  1177.     ; I doesn't change
  1178.     retclrc
  1179. notifx33:
  1180.  
  1181.      move.p2    #55,c
  1182.     brne.b    c,a,notifx55
  1183. ifx55:    ; save vars in memory
  1184.     call.3    varcopysetup
  1185. savelo:
  1186.     move.b    @d0,c        ; read a byte from variable
  1187.     move.b    c,@d1        ; store in MI
  1188.     swap.a    c,d0        ; get d0 to c
  1189.     move.a    c,d0
  1190.     brge.a    c,a,doret1    ; are we ready yet?
  1191.     add.a    2,d1
  1192.     add.a    2,d0
  1193.     move.a    r0,c        ; get I value
  1194.     inc.x    c        ; increment 3 low nibbles
  1195.     retcs            ; if carry, we might overwrite #1000
  1196.     move.a    c,r0        ; I changes permanently
  1197.     jump.3    savelo
  1198. doret1:
  1199.     retclrc
  1200.  
  1201. notifx55:
  1202.  
  1203.      move.p2    #65,c
  1204.     brne.b    c,a,notifx65
  1205. ifx65:    ; restore vars from memory
  1206.     call.3    varcopysetup
  1207. restolo:
  1208.     move.b    @d1,c        ; read a byte at MI
  1209.     move.b    c,@d0        ; store in variable
  1210.     swap.a    c,d0        ; get d0 to c
  1211.     move.a    c,d0
  1212.     brge.a    c,a,doret1    ; are we ready yet?
  1213.     add.a    2,d1
  1214.     add.a    2,d0
  1215.     move.a    r0,c        ; get I value
  1216.     inc.x    c        ; increment 3 low nibbles
  1217.     retcs            ; if carry, we wrapped around #1000
  1218.     move.a    c,r0        ; I changes permanently
  1219.     jump.3    restolo
  1220. notifx65:
  1221.     ; unknown FxNN instruction
  1222.     retsetc
  1223.  
  1224.  
  1225. ; save registers r0..r3
  1226. save_rregs:
  1227.     move.a    r4,a        ; get start of data area
  1228.     move.p5    ofs_regsave,c
  1229.     add.a    a,c
  1230.     move.a    c,d0
  1231.  
  1232.     move.a    r0,c
  1233.     move.a    c,@d0
  1234.     add.a    5,d0
  1235.     move.a    r1,c
  1236.     move.a    c,@d0
  1237.     add.a    5,d0
  1238.     move.a    r2,c
  1239.     move.a    c,@d0
  1240.     add.a    5,d0
  1241.     move.a    r3,c
  1242.     move.a    c,@d0
  1243.     add.a    5,d0
  1244.     ret
  1245.  
  1246.  
  1247. ; restore registers r0..r3
  1248. restore_rregs:
  1249.     move.a    r4,a        ; get start of data area
  1250.     move.p5    ofs_regsave,c
  1251.     add.a    a,c
  1252.     move.a    c,d0
  1253.  
  1254.     move.a    @d0,c
  1255.     move.a    c,r0
  1256.     add.a    5,d0
  1257.     move.a    @d0,c
  1258.     move.a    c,r1
  1259.     add.a    5,d0
  1260.     move.a    @d0,c
  1261.     move.a    c,r2
  1262.     add.a    5,d0
  1263.     move.a    @d0,c
  1264.     move.a    c,r3
  1265.     add.a    5,d0
  1266.     ret
  1267.  
  1268.  
  1269. ; sprite: draw a CHIP-8 "sprite", 8 pixels wide by 1..15 pixels high
  1270. ;
  1271. ; in: r0.a  points to sprite data
  1272. ;     a.a   contains x coordinate
  1273. ;     d.a   contains y coordinate
  1274. ;     c.14  zero initial value for collision flag
  1275. ;     c.15  number of lines in sprite
  1276. ; out: c.14 collision flag
  1277. ;
  1278. ; register usage:
  1279. ; a,c used for scratch
  1280. ;  c.15 contains sprite byte (line) count
  1281. ;  c.14 contains collision flag
  1282. ;  c.13 is used as temporary save location for p
  1283. ;  c.12 is nonzero in "short mode" (2x1 pixels)
  1284. ; b contains the byte to display
  1285. ; d contains the 32-bit pixel string
  1286. ; r0 points to sprite data
  1287. ; r1 points to linetab
  1288. ; r2 contains the X offset in nibbles from the beginning of the lcd line
  1289. ; r3 contains entry point to pixel alignment shifts
  1290.  
  1291. sprite:
  1292.     move.1    12,p
  1293.     move.p1    0,c        ; set "short flag"
  1294.     move.1    0,p
  1295.  
  1296.     move.1    12,p
  1297.     brnz.p    c,short1    ; "short mode"?
  1298.     add.a    a,a        ; 2Y (the chip-8 pixels are 2 lines high)
  1299. short1:    move.1    0,p        ; (but not in "short mode"
  1300.  
  1301.     move.a    a,c        ; multiply by 5 to get index into linetab
  1302.     add.a    a,a
  1303.     add.a    a,a
  1304.     add.a    a,c        ; now c contains index to linetab
  1305.  
  1306.     move.a    r4,a        ; get start of data area
  1307.     add.a    c,a
  1308.     move.p5    ofs_linetab,c
  1309.     add.a    a,c
  1310.  
  1311.     move.a    c,r1        ; r1 is the linetab pointer
  1312.  
  1313.     ; calculate X offset in nibbles from the beginning of the lcd line
  1314.     move.a    d,c        ; c = X
  1315.     srb.a    c        ; convert pixels to pixel octets
  1316.     srb.a    c
  1317.     srb.a    c
  1318.     add.a    c,c        ; convert pixel octets to nibbles
  1319.     add.a    c,c
  1320.     move.a    c,r2        ; r2 contains offset from beginning of line
  1321.  
  1322.     ; calculate entry point to alignment shifts
  1323.     move.p2    #07,c        ; d should still contain X
  1324.     and.b    c,d        ; mask out 3 low bits
  1325.     add.a    d,d        ; the shift instructions are 2 nibbles each
  1326.     move.a    pc,a        
  1327. ref11:    move.p5    shifts-ref11,c
  1328.     add.a    a,c
  1329.     add.a    d,c
  1330.     move.a    c,r3        ; r3 now contains entry point to shifts
  1331.  
  1332. linelo:
  1333.     move.a    r0,c        ; get sprite pointer
  1334.     move.a    c,d0
  1335.     move.2    @d0,c        ; byte to display
  1336.     clr.a    b
  1337.     move.b    c,b        ; ..to low byte of b; next byte is clear
  1338.     swap.a    c,d0
  1339.     add.a    2,c        ; advance to next sprite byte
  1340.     move.a    c,r0        ; save sprite pointer
  1341.  
  1342.     ; the low byte of b now contains the sprite byte
  1343.  
  1344.     move.a    r3,c        ; get shift entry point
  1345.     jump.a    c        ; jump to the appropriate shift instruction
  1346.  
  1347.  
  1348. shifts:    add.a    b,b        ; two-nibble instructions
  1349.     add.a    b,b
  1350.     add.a    b,b
  1351.     add.a    b,b
  1352.     add.a    b,b
  1353.     add.a    b,b
  1354.     add.a    b,b
  1355.     add.a    b,b
  1356.  
  1357.     move.a    pc,a
  1358. ref2:    move.p5    pixtab-ref2,c
  1359.     add.a    c,a        ; beginning of pixtab is in a
  1360.  
  1361.     ; keep &pixtab[0] in a at all times
  1362.     clr.a    c
  1363.     move.p    b,c        ; extract a nibble from b
  1364.     add.a    c,c        ; times two
  1365.     add.a    a,c        ; add beginning of pixtab
  1366.     move.a    c,d0        ; point d0 to pixtab byte
  1367.     move.b    @d0,c
  1368.     move.b    c,d        ; now 8 more pixels in d
  1369.  
  1370.     sln.w    d
  1371.     sln.w    d
  1372.     srn.a    b
  1373.  
  1374.     clr.a    c
  1375.     move.p    b,c        ; extract a nibble from b
  1376.     add.a    c,c        ; times two
  1377.     add.a    a,c
  1378.     move.a    c,d0        ; point d0 to pixtab byte
  1379.     move.b    @d0,c
  1380.     move.b    c,d        ; now 8 more pixels in d
  1381.  
  1382.     sln.w    d
  1383.     sln.w    d
  1384.     srn.a    b
  1385.  
  1386.     clr.a    c
  1387.     move.p    b,c        ; extract a nibble from b
  1388.     add.a    c,c        ; times two
  1389.     add.a    a,c
  1390.     move.a    c,d0        ; point d0 to pixtab byte
  1391.     move.b    @d0,c
  1392.     move.b    c,d        ; now 8 more pixels in d
  1393.  
  1394.     sln.w    d
  1395.     sln.w    d
  1396.     srn.a    b
  1397.  
  1398.     clr.a    c
  1399.     move.p    b,c        ; extract a nibble from b
  1400.     add.a    c,c        ; times two
  1401.     add.a    a,c
  1402.     move.a    c,d0        ; point d0 to pixtab byte
  1403.     move.b    @d0,c
  1404.     move.b    c,d        ; now 8 more pixels in d
  1405.  
  1406.     ; now d contains 32 pixels
  1407.  
  1408.     move.a    r1,a        ; get linetab pointer
  1409.     move.a    a,d0        ; ..to d0
  1410.     move.a    @d0,c        ; address of current line to c
  1411.  
  1412.     move.1    12,p
  1413.     brnz.p    c,short2
  1414.     add.a    5,a        ; point 1 line ahead if "short mode",
  1415. short2:    add.a    5,a        ; point 2 lines ahead otherwise
  1416.     move.1    0,p
  1417.  
  1418.     move.a    a,r1        ; this is the new linetab pointer
  1419.  
  1420.     move.a    r2,a        ; X offset in nibbles
  1421.     add.a    a,c        ; add beginning of lcd line
  1422.     move.a    c,d0        ; now d0 points to display buffer
  1423.  
  1424.     ; now we operate on the display buffer with a word length
  1425.     ; that is normally 32 bits, but near the right end we
  1426.     ; must decrease it to avoid wrapping around and messing up
  1427.     ; the left part of the display.  Therefore the word length
  1428.     ; should be min(8, 32-xoff) nibbles.
  1429.  
  1430.     move.p2    32,c
  1431.     sub.b    a,c        ; now c = 32-xoff
  1432.     move.p2    8,a
  1433.     brlt.b    c,a,clip    ; if (32-xoff) is < 8, use that, else 8
  1434.     move.b    a,c
  1435. clip:    dec.b    c        ; .wp field is (p+1) nibbles; compensate
  1436.     move.1    c,0,p        ; set field size
  1437.  
  1438.     move.wp    @d0,c        ; get old display buffer contents
  1439.     move.wp    c,a        ; make a copy in a
  1440.     and.wp    d,c        ; now c = (old and new), a = old, d = new
  1441.     brz.wp    c,nocoll
  1442.  
  1443.     ; there has been a collision; set nibble 14 in c
  1444.     swap.1    p,c,13        ; save p in nibble 13 of c
  1445.     move.1    14,p
  1446.     move.p1    1,c        ; set collision flag in nibble 13 of c
  1447.     swap.1    p,c,13        ; restore p
  1448. nocoll:
  1449.     swap.wp    d,c        ; now d = (old and new), a = old, c = new
  1450.     or.wp    a,c        ; now c = (old or new)
  1451.     not.wp    d
  1452.     and.wp    d,c        ; now c = (old or new) and not(old and new)
  1453.  
  1454.     swap.1    p,c,13
  1455.     move.1    12,p
  1456.     brnz.p    c,short3
  1457.     swap.1    p,c,13
  1458.  
  1459.     move.wp    c,@d0        ; store once
  1460.     add.a    16,d0        ; advance by 34 to next scan line
  1461.     add.a    16,d0
  1462.     add.a    2,d0
  1463.     move.wp    c,@d0        ; store again
  1464.     jump.3    noshort3
  1465. short3:
  1466.     swap.1    p,c,13
  1467.     move.wp    c,@d0        ; store just once
  1468. noshort3:
  1469.     move.1    0,p
  1470.     
  1471.     dec.s    c
  1472.     brz.s    c,lineexit
  1473.     jump.3    linelo
  1474. lineexit:
  1475.  
  1476.     ret  ; sprite
  1477.  
  1478.  
  1479. ; this lookup table serves a dual purpose: it swaps the bits in a nibble
  1480. ; to convert from big-endian to little-endian format, and doubles each bit
  1481. ; to lower the resolution to 64 pixels horizontally.
  1482. pixtab:
  1483.     data.b    !00000000
  1484.     data.b    !11000000
  1485.     data.b    !00110000
  1486.     data.b    !11110000
  1487.     data.b    !00001100
  1488.     data.b    !11001100
  1489.     data.b    !00111100
  1490.     data.b    !11111100
  1491.     data.b    !00000011
  1492.     data.b    !11000011
  1493.     data.b    !00110011
  1494.     data.b    !11110011
  1495.     data.b    !00001111
  1496.     data.b    !11001111
  1497.     data.b    !00111111
  1498.     data.b    !11111111
  1499.  
  1500.  
  1501. ; 4x5 pixel hexadecimal character font patterns
  1502. hexfont:
  1503.     data.5 #F999F
  1504.     data.5 #72262
  1505.     data.5 #F8F1F
  1506.     data.5 #F1F1F
  1507.     data.5 #11F99
  1508.     data.5 #F1F8F
  1509.     data.5 #F9F8F
  1510.     data.5 #4421F
  1511.     data.5 #F9F9F
  1512.     data.5 #F1F9F
  1513.     data.5 #99F9F
  1514.     data.5 #E9E9E
  1515.     data.5 #F888F
  1516.     data.5 #E999E
  1517.     data.5 #F8F8F
  1518.     data.5 #88F8F
  1519. hexfontend:
  1520.  
  1521. ; powers of two in BCD, for binary-to-decimal conversion
  1522. dectab:    data.3 #001
  1523.     data.3 #002
  1524.     data.3 #004
  1525.     data.3 #008
  1526.     data.3 #016
  1527.     data.3 #032
  1528.     data.3 #064
  1529.     data.3 #128
  1530.  
  1531. ; table mapping Telmac hex key locations to HP48SX key codes
  1532. ; lsn is bit mask to output, lsn is bit mask to mask input with
  1533. keytab:
  1534.     data.2    #41
  1535.     data.2    #88
  1536.     data.2    #48
  1537.     data.2    #28
  1538.     data.2    #84
  1539.     data.2    #44
  1540.     data.2    #24
  1541.     data.2    #82
  1542.     data.2    #42
  1543.     data.2    #22
  1544.     data.2    #81
  1545.     data.2    #21
  1546.     data.2    #18
  1547.     data.2    #14
  1548.     data.2    #12
  1549.     data.2    #11
  1550.  
  1551. ; jump table for CHIP-8 instruction dispatching based on the first nibble
  1552.  
  1553. jumptab:
  1554.     data.4    i0-jtref
  1555.     data.4    i1-jtref
  1556.     data.4    i2-jtref
  1557.     data.4    i3-jtref
  1558.     data.4    i4-jtref
  1559.     data.4    i5-jtref
  1560.     data.4    i6-jtref
  1561.     data.4    i7-jtref
  1562.     data.4    i8-jtref
  1563.     data.4    i9-jtref
  1564.     data.4    ia-jtref
  1565.     data.4    ib-jtref
  1566.     data.4    ic-jtref
  1567.     data.4    id-jtref
  1568.     data.4    ie-jtref
  1569.     data.4    if-jtref
  1570.  
  1571. regsave:
  1572.     even    ; pad to even number of nibbles
  1573.  
  1574. end:    ; don't add stuff after this line.
  1575. ================================ Cut here ================================
  1576. -- 
  1577. Andreas Gustafsson
  1578. Internet: gson@niksula.hut.fi
  1579. Voice: +358 0 563 5592
  1580.  
  1581.  
  1582.